limit switch- home switch

[normd]

I am using 1842/2900 combo can I set the 3 limit switches to double as home switches? How?
Norm D

[Karl_T]

Here's my macros to home and park off the limit switches. It saves a buch of time at startup if machine is in park posiiton so i tell operator to do this before shutdown.


'*********************************PARK MACHINE****************************************
[[PARKMACHINE]] 'called from M111
IF \140=1 THEN MESSAGE . Start of Park Machine

IF \141=1 THEN [GALILERRORS] 'message Galil errors
IF #59=0 THEN MESSAGE Need a Reset:EXIT
\124=f 'current feed rate
f=20
MACHGO ;;0
MACHGO ;0
MACHGO 0
f={\124}
MESSAGE Machine Parked
IF \141=1 THEN [GALILERRORS] 'message Galil errors





'**************************************HOME MACHINE*************************************
[[HOMEMACHINE]] 'called from M110
IF \140=1 THEN MESSAGE . Start of HomeMachine
IF #59=0 THEN MESSAGE Need a Reset:EXIT
QUESTION Is machine at limit switches?;\55;N
IF \55=Y THEN GOTO :STARTHOME
EXIT
:STARTHOME

IF \141=1 THEN [GALILERRORS] 'message Galil errors

MACHZERO 0;0;0 'set machine zero point temporarily for this macro

SUSPEND BYPASS 'suspends position checking for MACHGO move
MACHGO ;10 'move toward limit switch
WAITUNTIL #12=1 'foward limit switch Y axis
STOP 'stop when switch is hit
FINDINDEX 2;R 'find Y axis index mark

SUSPEND BYPASS 'suspends position checking for MACHGO move
MACHGO -10 'move toward limit switch
WAITUNTIL #6=1 'reverse limit switch X axis
STOP 'stop when switch is hit
MACHZERO 0;0;0 'set machine zero point temporarily for this macro
GO .05 'index mark too close to limit switch
FINDINDEX 1;F

SUSPEND BYPASS 'suspends position checking for MACHGO move
MACHGO ;;10 'move toward limit switch
WAITUNTIL #13=1 'reverse limit switch Z axis
STOP 'stop when switch is hit
FINDINDEX 3;R

MACHZERO 0;0;0 'set machine zero point
LIGHT 5;ON
\123=1 'flag for machine homed
MESSAGE AT MACHINE 0
IF \141=1 THEN [GALILERRORS] 'message Galil errors